1000 :
1010 REM  DYNAMIC RENEWING PROGRAM
1020 REM  T.S. CREASY SEPTEMBER 1983
1030 :
1040 REM  INSTRUCTIONS
1050 :
1051 PRINT"[147][176][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][174]":PRINT"[221]DYNAMIC RENEW DISK [221]"
1052 PRINT"[173][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][192][189]"
1053 FORX=1TO1000:NEXT
1060 PRINT"THIS PROGRAM MODIFIES":PRINT"ITSELF BY THE DYNAMIC"
1070 PRINT"KEYBOARD TECHNIQUE.":PRINT"ONCE MODIFIED, IT "
1080 PRINT"CANNOT BE USED WITH ":PRINT"ANY DISK EXCEPT THE ONE"
1090 PRINT"IT WAS MODIFIED FOR.":PRINT"DURING THE DYNAMIC"
1100 PRINT"MODIFICATION THE SCREEN":PRINT"WILL FLASH WITH"
1110 PRINT"THE NEW PROGRAM LINES":OPEN50,0:PRINT"PRESS RETURN":INPUT#50,K$:CLOSE50
2000 :
2010 REM ATTACH DATA STATEMENTS
2020 REM OF TRACKS AND SECTORS
2030 :
2032 PRINT"[147]5 DATA"PEEK(822)
2033 PRINT"GOTO2050"
2034 POKE631,13:POKE632,13:REM POKE CARRIAGE RETURNS INTO K BUFFER
2035 POKE198,2:REM NUMBER OF RETURNS
2036 STOP
2050 I=0:LN=10:J=PEEK(822)
2060 PRINT"[147]"(LN+I)"DATA"PEEK(823+I)","PEEK(823+I+J)
2070 PRINT"GOTO2120"
2080 POKE631,13:POKE632,13:REM POKE CARRIAGE RETURNS INTO K BUFFER
2090 POKE198,2:REM NUMBER OF RETURNS
2100 POKE820,I:REM SAVE I IN C BUFFER
2105 POKE821,LN:REM SAVE LN IN C BUFFER
2110 STOP
2120 I=PEEK(820)+1:LN=PEEK(821)+1:J=PEEK(822)
2130 IF I<PEEK(822)THEN2060
3000 :
3010 REM FORCE SKIP TO VALIDATE
3020 REM PORTION OF THE PROGRAM
3030 :
3040 PRINT"[147]1 GOTO 4000":PRINT"GOTO6000"
3060 POKE631,13:POKE632,13:REM POKE CARRIAGE RETURN INTO K BUFFER
3080 POKE198,2:REM NUMBER OF RETURNS
3090 STOP
4000 :
4010 REM NEW DISK WITH OPERATOR
4020 REM INTERACTION
4030 :
4040 PRINT"[147][176][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][174]"
4050 PRINT"[209] RENEW DISK        [209]"
4060 PRINT"[209] BAD SECTORS       [209]"
4070 PRINT"[173][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][209][189]"
4080 PRINT"INSERT DISK IN DRIVE":PRINT"PRESS RETURN"
4090 OPEN50,0:INPUT#50,K$:CLOSE50
4100 PRINT"INITIALIZING DISK"
4110 OPEN15,8,15,"I":INPUT#15,E,M$,TR,SE
4115 OPEN5,8,5,"#": REM OPEN BUFFER
4120 IFE<>0THENPRINT"DISK ERROR#"E:END
4130 PRINT#15,"B-R:"5;0;18;0:REM PLACE DISK HEADER IN BUFFER #
4140 PRINT#15,"B-P:"5;144:REM SET POINTER TO DISK NAME
4150 D$="":FORX=144TO166:GET#5,K$:D$=D$+(CHR$(0)+K$):NEXT:REM DISK NAME
4160 PRINT"DISK NAME:":PRINT""D$
4170 INPUT"RENEW DISK (ERASING ALL FILES)[146]  N[146][157][157][157]";K$
4180 IFK$<>"Y"THENCLOSE5:CLOSE15:END
4190 INPUT"ENTER NEW NAME";K$
4200 PRINT"NAME:"K$:INPUT"IS NAME CORRECT  Y[146][157][157][157]";A$
4210 IFA$<>"Y"THEN4190
4220 PRINT#15,"N0:"K$:PRINT"NEWING DISK"
4998 CLOSE5:CLOSE15
5000 :
5010 REM ALLOCATE BAD BLOCKS
5020 :
5030 OPEN15,8,15,"V":PRINT"[147]VALIDATING THE DISK"
5040 OPEN2,8,2,"#"
5050 PRINT"[147]   BAD BLOCKS":PRINT"TRACK","SECTOR"
5060 READ J:I=0
5070 READ TR,SE
5080 PRINT#15,"B-A:";0;TR;SE
5090 PRINTTR,SE
5100 I=I+1:IF I=J THEN 5120
5110 GOTO5070
5120 FORX=1TO3000:NEXT
5130 PRINT"[147]"J"BAD SECTORS HAVE":PRINT"BEEN REMOVED FROM USE."
5140 PRINT"DO NOT VALIDATE  ":PRINT"DATA MAY BE LOST!"
5150 CLOSE15
5160 FORX=1TO1000:NEXT
6000 :
6010 REM SAVE SELF TO DISK
6020 :
6030 PRINT"[147]PLACE DISK WITH BAD":PRINT"BLOCKS IN DRIVE"
6040 OPEN50,0:PRINT"PRESS RETURN":INPUT#50,K$
6050 PRINT"SAVING THIS PROGRAM"
6060 SAVE"@0:RENEW THIS DISK",8
6080 PRINT"[147]NEVER VALIDATE THIS":PRINT"DISK. COPY FILES TO ":PRINT"ANOTHER DISK, THEN"
6090 PRINT"LOAD AND RUN THIS":PRINT"PROGRAM TO RENEW THE":PRINT"DISK WITH AUTOMATIC"
6100 PRINT"'BAD SECTOR' HANDLING.":PRINT"NEVER VALIDATE THIS DISK"
6110 PRINT"THIS PROGRAM HAS BEEN":PRINT"MODIFIED FOR THIS":PRINT"DISK ONLY"
6120 PRINT"DO NOT USE THIS     ":PRINT"PROGRAM WITH ANOTHER":PRINT"DISK::::            "
7110 PRINT"THE DISK IS PREPARED"